(********************************************************************)
(*  OCaml code from the book ``Learn Programming with OCaml''       *)
(*  See https://usr.lmf.cnrs.fr/lpo/                                *)
(*                                                                  *)
(*  Sylvain Conchon and Jean-Christophe Filliâtre                   *)
(*  Copyright 2025 Université Paris-Saclay and CNRS                 *)
(*                                                                  *)
(*  Openly licensed via CC BY SA 4.0                                *)
(*  See https://creativecommons.org/licenses/by-sa/4.0/deed.en      *)
(********************************************************************)

(* Program 94 on page 392
   Merge sort on arrays *)

  let merge a1 a2 l m r =
    let i = ref l in
    let j = ref m in
    for k = l to r - 1 do
      if !i < m && (!j = r || le a1.(!i) a1.(!j)) then begin
        a2.(k) <- a1.(!i); incr i
      end else begin
        a2.(k) <- a1.(!j); incr j
      end
    done

  let mergesort a =
    let tmp = Array.copy a in
    let rec mergesort_rec l r =
      if l < r - 1 then begin
        let m = (l + r) / 2 in
        mergesort_rec l m;
        mergesort_rec m r;
        Array.blit a l tmp l (r - l);
        merge tmp a l m r
      end
    in
    mergesort_rec 0 (Array.length a)
  

This document was generated using caml2html