(********************************************************************)
(*  OCaml code from the book ``Learn Programming with OCaml''       *)
(*  See https://usr.lmf.cnrs.fr/lpo/                                *)
(*                                                                  *)
(*  Sylvain Conchon and Jean-Christophe Filliâtre                   *)
(*  Copyright 2025 Université Paris-Saclay and CNRS                 *)
(*                                                                  *)
(*  Openly licensed via CC BY SA 4.0                                *)
(*  See https://creativecommons.org/licenses/by-sa/4.0/deed.en      *)
(********************************************************************)

(* Program 93 on page 388
   Merge sort on lists *)

  let rec split l1 l2 = function
    | [] -> (l1, l2)
    | x :: l -> split (x :: l2) l1 l

  let rec merge acc l1 l2 = match l1, l2 with
    | [], l | l, [] ->
        List.rev_append acc l
    | x1 :: s1, x2 :: s2 ->
        if le x1 x2 then merge (x1 :: acc) s1 l2
        else merge (x2 :: acc) l1 s2

  let rec mergesort l = match l with
    | [] | [_] ->
        l
    | _ ->
        let l1, l2 = split [] [] l in
        merge [] (mergesort l1) (mergesort l2)
  

This document was generated using caml2html