(********************************************************************)
(*  OCaml code from the book ``Learn Programming with OCaml''       *)
(*  See https://usr.lmf.cnrs.fr/lpo/                                *)
(*                                                                  *)
(*  Sylvain Conchon and Jean-Christophe Filliâtre                   *)
(*  Copyright 2025 Université Paris-Saclay and CNRS                 *)
(*                                                                  *)
(*  Openly licensed via CC BY SA 4.0                                *)
(*  See https://creativecommons.org/licenses/by-sa/4.0/deed.en      *)
(********************************************************************)

(* Program 103 on page 431
   Minimum spanning tree *)

  let spanning_tree g =
    let uf = UF.create (vertices g) in
    let compare (_,_,w1) (_,_,w2) = Stdlib.compare w1 w2 in
    let edges = List.sort compare (edges g) in
    let st = ref [] in
    let cover ((u, v, w) as e) =
      if UF.find uf u <> UF.find uf v then begin
        UF.union uf u v;
        st := e :: !st
      end
    in
    List.iter cover edges;
    !st

This document was generated using caml2html